Есть ли в libxslt возможность разбивать документ на несколько документов?

Похоже, libxslt не поддерживает XSLT 2.0 и xsl:result-document. Есть ли способ имитировать xsl:result-document, используя libxslt или xsltproc?

6 голосов | спросил Behrang 2 J000000Friday10 2010, 21:41:50

3 ответа


0

Да, есть, используя exsl: document . Простой пример:

==== foo.xsl ====
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:output method="html"/>
  <xsl:template match="/">
    <exsl:document href="toc.html" method="html">
      <html>
        <body>
          <xsl:apply-templates select=".//h1"/>
        </body>
      </html>
    </exsl:document>
    <xsl:apply-templates/>
  </xsl:template>
  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

принимая это как входные данные:

==== foo.html ====
<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

при запуске так:

xsltproc foo.xsl foo.html

выдаст это stdout:

<html>
  <body>
    <h1>Hello, world!</h1>
    <p>Some longwinded text follows.</p>
  </body>
</html>

во время записи этого в toc.html:

<html><body><h1>Hello, world!</h1></body></html>
ответил Owen S. 3 J000000Saturday10 2010, 02:31:54
0

Если libxslt реализует EXSLT , то вы можете использовать <exsl:document> элемент расширения.

Если нет, то вы должны написать свои собственные функции расширения, поскольку XSLT 1.0 не поддерживает создание нескольких документов результатов.

Обновление : как подтверждено в этот комментарий , libxslt реализует EXSLT. Просто возьмите его и используйте <exsl:document> .

ответил Dimitre Novatchev 2 J000000Friday10 2010, 22:21:13
0

А вот пример, который показывает, как использовать расширение для создания неограниченного количества файлов при обходе набора узлов. Опять же, используя xsltproc (libxslt)

Пример ввода XML:

<clients>
    <client id="ACME1" name="ACME Company 1"/>
    <client id="ACME2" name="ACME Company 2"/>
    <client id="ACME3" name="ACME Company 3"/>
</clients>

Образец XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" 
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

<xsl:output method="html" indent="yes" encoding="UTF-8" />

<xsl:template match="/">
    <xsl:for-each select="/clients/client">
    <exsl:document href="{@id}.html" method="html">
      <html>
        <body>
          <h1>Company: <xsl:apply-templates select="@name"/></h1>
        </body>
      </html>
    </exsl:document>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

создаст 3 файла ACME1.html, ACME2.html и т. д.

ответил John Nash 7 thEurope/Moscowp30Europe/Moscow09bEurope/MoscowMon, 07 Sep 2015 00:41:01 +0300 2015, 00:41:01

Похожие вопросы

Популярные теги

security × 330linux × 316macos × 2827 × 268performance × 244command-line × 241sql-server × 235joomla-3.x × 222java × 189c++ × 186windows × 180cisco × 168bash × 158c# × 142gmail × 139arduino-uno × 139javascript × 134ssh × 133seo × 132mysql × 132